• Tùy chọn
• Đăng nhập
• Đăng ký
• Xem như trên Máy tính
• Accelerated Mobile Pages Theme

Đánh số TT trong Query hoặc Form

• Trang chủ

  • Thủ Thuật Access
  • Access Cơ Bản
  • Query
  • Đánh số TT trong Query hoặc Form
• Đánh số TT trong Query hoặc Form

• RE: Đánh số TT trong Query hoặc Form

  MTNQ > 26-07-15, 07:43 PM

  Theo MTNQ thì ý của chủ thớt là trên Single Form và câu trả lời đầu tiên của bác Ân là chính xác rùi 
  (Không biết bạn wintq  còn đây không nhỉ, sao không thấy hồi âm gì vậy   )
  
  Câu hỏi của bạn Minh Tiên  là trên Continuous Forms (hay Datasheet)  thì lại khác,  không dùng  =[Form].[CurrentRecord] được, có một số cách đánh số thứ tự cho trường hợp này. MTNQ xin giới thiệu cách dùng thuộc tính AbsolutePosition của Recordset (Link tham khảo AbsolutePosition  )
  
  -Chép hàm sau vào một Module bất kỳ:
  

  Mã:

  Public Function fSTT(frm As Form) As Variant
On Error GoTo Err_fSTT
   With frm.RecordsetClone
       .Bookmark = frm.Bookmark
       fSTT = .AbsolutePosition + 1
   End With
   
Exit_fSTT:
   Exit Function
   
Err_fSTT:
   If Err.Number <> 3021 And Err.Number <> 2196 Then
       Debug.Print "fSTT() error " & Err.Number & " - " & Err.Description
   End If
   fSTT = Null
   Resume Exit_fSTT
End Function

  
   -Text box STT gán Controle Source: =fSTT([Form])
  
  Demo 
  (Lười tạo table nên mượn đỡ Data của một bạn nào đó trên diễn đàn, các bạn thông cảm nha  )
  
  Lưu ý: 
  -Với DAO thì Record đầu tiên có AbsolutePosition = 0 còn ADO thì =1. Nếu sử dụng ADO thì thay dòng  fSTT = .AbsolutePosition + 1 bằng  fSTT = .AbsolutePosition

• RE: Đánh số TT trong Query hoặc Form

  MTNQ > 26-07-15, 10:31 PM

  Đọc lại chủ đề thấy còn một vế nữa: đánh STT trong Query ?
  
  Làm thử thấy có vẻ nhanh hơn dùng hàm fSTT() 
  
  Demo STT Tren Form2.rar

• RE: Đánh số TT trong Query hoặc Form

  Minh Tiên > 28-07-15, 11:36 AM

  Thanks tranthanhan1962 và Mattroinguquen nhiều !
  Cách tạo stt bằng query và tạo trực tiếp dùng code như 2 bác giới thiệu Tiên đã làm rồi.
  1. Cách tạo bằng code Fill trực tiếp stt trên Form (Hoặc Edit số trong table rồi Boundcontrol vào STT) chỉ dùng cho hiển thị ít số liệu, chứ vài chục ngàn record --> đợi xỉu (Tiên đã thử hiển thị 10.000 Record rồi).
  2. Cách tạo số tt trong query thì rất nhanh, nhưng mình đang nghiên cứu ADODB, muốn có query phải tạo table, load dữ liệu từ File data về, ... rất cồng kềnh; Còn tạo SQL rồi load dữ liệu về thì có một số Stt phải tạo qua 2 cấp (2 query) mới hiển thị được --> SQL ko thực hiện được.
  Các Pro còn có cách tạo, hiển thị số tt (bằng Unbound) nào khác, nhanh hơn cách 1 ko ? Chia sẻ với !
  Thanks !

• RE: Đánh số TT trong Query hoặc Form

  MTNQ > 29-07-15, 02:05 AM

  (28-07-15, 11:36 AM)Minh Tiên Đã viết: Thanks tranthanhan1962 và Mattroinguquen nhiều !
  Cách tạo stt bằng query và tạo trực tiếp dùng code như 2 bác giới thiệu Tiên đã làm rồi.
  1. Cách tạo bằng code Fill trực tiếp stt trên Form (Hoặc Edit số trong table rồi Boundcontrol vào STT) chỉ dùng cho hiển thị ít số liệu, chứ vài chục ngàn record --> đợi xỉu (Tiên đã thử hiển thị 10.000 Record rồi).
  ...

  
  Bạn thử hàm fSTT  chưa nhỉ, thấy cũng OK lém mà , đâu đến nỗi... xỉu 
  Mình lấy Data trong chủ đề về ADO, thêm vào 100 000 mẩu tin, dùng hàm fSTT như trên, load toàn bộ lên form chưa đầy 1 giây
  
  Bạn xem thử nha (mình làm mdb để tiện cho các bạn dùng AC 2003)
  
  Demo STT (ADO).rar

• RE: Đánh số TT trong Query hoặc Form

  ledangvan > 11-09-15, 10:04 PM

  Dựa vào bài của MatTroiNguQuen mình có làm thử một cái đánh lại số thứ tự, mình định làm như sau :
  Có một bảng do người sử dụng nhập vào : Ngày CT, Số CT ....; 
  Sau khi đánh xong mục Số CT do một số lý do nào đó người dùng muốn đánh lại nó theo thứ tự 
  
  Mình có thêm một cột STT : Lấy theo kiểu của MatTroiNguQuen ; mình có một nút Tích chuyển -> Mục đích là muốn copy toàn bộ cột STT thay thế cho cột Số CT
  Tuy nhiên khi Tích chuyển thì máy nó chỉ hiểu giá trị STT tại con trỏ và chuyển hết thành 1 số
   Mình muốn ai biết chỉnh hộ cái sai trong bài : http://www.mediafire.com/download/z0u242...+So+TT.rar
  Xin chân thành cảm ơn.

• RE: Đánh số TT trong Query hoặc Form

  MTNQ > 12-09-15, 03:59 PM

  Bác tham khảo 3 thủ tục sau:
  
   Thủ tục 1:
  

  Mã:

  Sub Test1()
    'Application.Echo False
   If Me.Recordset.RecordCount = 0 Then Exit Sub
   DoCmd.GoToRecord , , acFirst
   Do
       Me.SoCT = Me.STT
       DoCmd.GoToRecord , , acNext
   Loop Until IsNull(Me.HDID)
   'Application.Echo True
End Sub

  
  Thủ tục 2:
  

  Mã:

  Sub Test2()
   With Me.Recordset.Clone
      If Not .EOF Then .MoveFirst
      Do While Not .EOF And Not .BOF
       CurrentDb.Execute "UPDATE Hoadon SET SoCT = 'C " & .AbsolutePosition + 1 & "' " & _
         "WHERE HDID = " & .HDID
       .MoveNext
      Loop
  End With
 
  Me.Requery
End Sub

  
  Thủ tục 3 :
  

  Mã:

  Sub Test3()
   With Me.Recordset.Clone
      If Not .EOF Then .MoveFirst
      Do While Not .EOF And Not .BOF
       .Edit
       .SoCT = "C " & .AbsolutePosition + 1
       .Update
       .MoveNext
      Loop
  End With
  Me.Requery
End Sub

  
   -Cả 3 phương án trên  dùng cách nào cũng được
  -Với Test1: Có thể dùng Application.Echo False nhằm tắt chế độ cập nhật từng mẫu tin lên màn hình, -> mã chạy nhanh hơn
  P/S: Bác nên bỏ sắp xếp theo cột SoCT, vì cột này có  kiểu dữ liệu là Text nên nó sẽ sắp theo abc: c1, c11, c2... Khi load lại form sẽ không trùng khớp với cột STT

• RE: Đánh số TT trong Query hoặc Form

  MTNQ > 12-09-15, 04:40 PM

  Ví dụ trên File của bác :
  
  
  http://www.mediafire.com/download/8te0aq...+So+TT.rar
  
  Chỉ là đưa ra phương án thui, chưa có bẫy lỗi... Bác tùy biến nhé  

• RE: Đánh số TT trong Query hoặc Form

  Minh Tiên > 27-11-19, 09:52 AM

  (29-07-15, 02:05 AM)MTNQ Đã viết:

  (28-07-15, 11:36 AM)Minh Tiên Đã viết: Thanks tranthanhan1962 và Mattroinguquen nhiều !
  Cách tạo stt bằng query và tạo trực tiếp dùng code như 2 bác giới thiệu Tiên đã làm rồi.
  1. Cách tạo bằng code Fill trực tiếp stt trên Form (Hoặc Edit số trong table rồi Boundcontrol vào STT) chỉ dùng cho hiển thị ít số liệu, chứ vài chục ngàn record --> đợi xỉu (Tiên đã thử hiển thị 10.000 Record rồi).
  ...

  
  Bạn thử hàm fSTT  chưa nhỉ, thấy cũng OK lém mà , đâu đến nỗi... xỉu 
  Mình lấy Data trong chủ đề về ADO, thêm vào 100 000 mẩu tin, dùng hàm fSTT như trên, load toàn bộ lên form chưa đầy 1 giây
  
  Bạn xem thử nha (mình làm mdb để tiện cho các bạn dùng AC 2003)
  
  Demo STT (ADO).rar

  Bạn MTNQ ơi ! Hôm nay mình đánh thức bạn tí nhé !
  Lâu nay mình sài Code đánh số tt của bạn, chạy OK trên form, nhưng có phát sinh lỗi lỗi trong môi trường Debug. Mỗi lần mở form đều phát sinh 2 dòng lỗi hoàn toàn giống nhau. Cụ thể:
  Nếu dùng code:
  

  Mã:

  With mfrm.Recordset.Clone
      .Bookmark = mfrm.Bookmark
      fTaoStt = .AbsolutePosition + 1
  End With

  Thì phát sinh 2 dòng lỗi:
  fTaoStt() error 91 - Object variable or With block variable not set
  fTaoStt() error 91 - Object variable or With block variable not set
  Còn nếu dùng code:
  

  Mã:

  With mfrm.RecordsetClone
      .Bookmark = mfrm.Bookmark
      fTaoStt = .AbsolutePosition + 1
  End With

  Thì phát sinh 2 dòng lỗi:
  fTaoStt() error 7951 - You entered an expression that has an invalid reference to the RecordsetClone property.
  fTaoStt() error 7951 - You entered an expression that has an invalid reference to the RecordsetClone property.
  Bạn xem giúp mình nguyên nhân phát sinh lỗi nhé !
  Cách khắc phục: Bẫy lỗi loại trừ Err.Number<>7951 và Err.Number<>91 là Ko hiển thị nữa, nhưng mình ko biết lỗi này là do gì ?
  Thân./.

• RE: Đánh số TT trong Query hoặc Form

  ongke0711 > 27-11-19, 10:24 AM

  Bạn xem lại đã có Set Recordset cho Form chưa?
  Thường thì sẽ báo lỗi do Form chỉ mới có RecordSource nhưng Recordset của nó thì chưa Set, nên thuộc tính RecordsetClone hay liên quan đến Recordset đều không sử dụng được.

• RE: Đánh số TT trong Query hoặc Form

  tranthanhan1962 > 28-11-19, 10:35 AM

  Lâu lắm rồi mình mới thấy lại chủ đề này, lúc trước cũng có tham gia nhưng sau đó quên bẳng đi rồi thôi! Nhưng mà vấn đề này cũng làm cho mình suy nghĩ nhiều. Thực ra đây là vấn đề xếp thứ tự record trong table. ID autonumber thực ra là một field xếp tứ tự trong table. Nhưng nó sẽ khóa chết số ID vào record, nó cứ đẻ ra thêm số thứ tự liên tục nhưng khi một record bị xóa thì lộ ra những khoảng trống của những số thứ tự bị mất, làm cho số thứ tự không còn liên tục, có nhiều phương pháp để đánh lại số thứ tự trên query hay trên form, nhưng thường là phức tạp, chạy rất nặng v.v...
  Nghĩ mãi thì chỉ thấy xóa field ID này và tạo lại là nhanh nhất, nhưng nếu làm thủ công thì không khả thi  đối với các phần mềm (chẳng lẽ dạy cho người sử dụng mở table xóa field ID rồi tạo lại   ). Cuối cùng cũng tìm được mã VBA để xử lý.
  Ví dụ table tên là DANHSACH và field là STT (AutoNumber).
  Mã VBA xóa field STT:
  

  Mã:

  CurrentDb.TableDefs("DANHSACH").Fields.Delete "STT"

  Function VBA tạo lại field STT:
  
  

  Mã:

  Function CreateAutoNumberField(ByVal strTableName As String, ByVal strFieldName As String) As Boolean
On Error GoTo Err_CreateAutoNumberField
    
    Dim db As DAO.Database
    Dim fld As DAO.field
    Dim tdef As DAO.TableDef
    
    Set db = Application.CurrentDb

    Set tdef = db.TableDefs(strTableName)
    Set fld = tdef.CreateField(strFieldName, dbLong)
    With fld
        .Attributes = .Attributes Or dbAutoIncrField
    End With
    With tdef.Fields
        .Append fld
        .Refresh
    End With
   
    CreateAutoNumberField = True
   
Exit_CreateAutoNumberField:

    Set fld = Nothing
    Set tdef = Nothing
    Set db = Nothing
    Exit Function
   
Err_CreateAutoNumberField:
    CreateAutoNumberField = False
    With Err
        MsgBox "Error " & .Number & vbCrLf & .Description, vbOKOnly Or vbCritical, "CreateAutonumberField"
    End With
    Resume Exit_CreateAutoNumberField
   
End Function

  Sau khi xóa field STT thì gọi function CreateAutoNumberField, nó sẽ tạo lại danh sách số thứ tự liên tục.
  

  Mã:

  Call CreateAutoNumberField("DANHSACH", "STT")

  *Chú ý, Khi xóa, tạo lại field thì table phải được đóng, field STT không được làm Primary Key, Nếu muốn đánh số thứ tự theo field nào thì thiết đặt Indexes cho field đó
• Bài trước Bài tiếp