• Tùy chọn
• Đăng nhập
• Đăng ký
• Xem như trên Máy tính
• Accelerated Mobile Pages Theme

Trích xuất dữ liệu

• Trang chủ

  • Thủ Thuật Access
  • Access Cơ Bản
  • Thành viên giúp nhau
  • [Help] Trích xuất dữ liệu
• Trích xuất dữ liệu

• RE: Trích xuất dữ liệu

  ongke0711 > 18-04-16, 03:42 PM

  - Báo lỗi do kết nối query của bạn có thêm tham số điều kiện. Để OpenRecordset là 1 Query có điều kiện phải làm cách khác chứ không Open như Table (thuần tuý Select Query không có đk thì mở được, không báo lỗi).
  - Để OpenRecordset là 1 Query có điều kiện thì có 2 cách:
  Cách 1: Chạy Query bằng câu lệnh SQL. Cách này thường dùng.
  - Bạn để ý cách truyền tham số sau dấu "&".
  - Tại sao có lệnh rs.MoveFirst? Vì Query này của bạn có thể trả về nhiều dòng, do vậy để cập nhật tất cả các dòng bạn phải cho con trỏ di chuyển về dòng đầu tiên của Recordset, sau đó update, sau đó di chuyển qua dòng kế tiếp (rs.MoveNext) và update. Lặp lại hoạt động này cho đến khi đến dòng cuối của Recordset thì ngưng (rs.EOF).
  - Có trường hợp Recordset trả về không có dòng nào thì chương trình sẽ báo lỗi do vậy thêm dòng lệnh If rs.RecordCount>0...
   
  

  Mã PHP:

  Dim rs As DAO.Recordset, strSQL As String
   strSQL = "SELECT Nhaphoso.SoQD, Nhaphoso.NgayKetqua, Nhaphoso.Nguoicocong, Nhaphoso.Nguoihuonghangthang, Nhaphoso.Nguoihuongmotlan, Nhaphoso.Xa, Nhaphoso.Huyen, Nhaphoso.LoaiHS, Nhaphoso.Doituong, Nhaphoso.NguoiGQ, Nhaphoso.Ngaynhan, Nhaphoso.GhichuKQ " & _
           "FROM Nhaphoso " & _
           "WHERE Nhaphoso.SoQD Is Not Null AND Nhaphoso.Doituong = '" & [Forms]![frmlocloaihoso]![cbolocdoituongtg] & "' AND Nhaphoso.Ngaynhan BETWEEN #" & [Forms]![frmlocloaihoso]![txtngaydau] & "# And #" & [Forms]![frmlocloaihoso]![txtngaysau] & "#"
   Set rs = CurrentDb.OpenRecordset(strSQL, dbOpenDynaset)
   If rs.RecordCount > 0 Then
       rs.MoveFirst
   Else
       Exit Sub
   End If
   With rs
       Do Until .EOF
           .Edit
           !GhichuKQ = !GhichuKQ & "-" & Me.txtngaydau
           .Update
           .MoveNext
       Loop
   End With
   rs.Close
   Set rs = Nothing 


  
  Cách 2: sử dụng Query đã tạo sẳn (như "qrybaocaotheothoigian" của bạn). 
  - Vì Query này có lấy 2 tham số từ form nên khi OpenRecordset từ query này phải khai báo lại tham số điều kiện.
  

  Mã PHP:

  Dim rs As DAO.Recordset, qdf As QueryDef, prm As Parameter
    Set qdf = CurrentDb.QueryDefs("qrybaocaotheothoigian")
   For Each prm In qdf.Parameters
       prm.Value = Eval(prm.Name)
   Next
   Set rs = qdf.OpenRecordset(dbOpenDynaset)
   If rs.RecordCount > 0 Then
       rs.MoveFirst
   Else
       Exit Sub
   End If
   With rs
       Do Until .EOF
           .Edit
           !GhichuKQ = !GhichuKQ & "-" & Me.txtngaydau
           .Update
           .MoveNext
       Loop
   End With
   rs.Close
   Set rs = Nothing 

• Bài trước Bài tiếp