Tùy chọn
Thuộc tính Startup MS Access toàn tập với VBA
- Thuộc tính Startup MS Access toàn tập với VBA
-
Thuộc tính Startup MS Access toàn tập với VBA
Noname > 26-08-10, 08:49 PM
Xin chào các tín đồ Access. Có lẽ nhiều người biết các ngăn chặn vọc phá cũng như tùy biến thuộc tính startup Access bằng cách vào Tool--> Startup.
Tuy nhiên, không phải bao giờ điều đó cũng làm các bạn hài lòng, và chúng ta luôn luôn muốn hơn nữa với VBA.Sau đây, mình xin giới thiệu các lệnh sửa thuộc tính trong VBA. Có lẽ vài bạn đã từng thử với việc Disable phím shift. Nhưng trong phạm vi bài viết này, mình sẽ nêu đầy đủ hơn về các thuộc tính đó.Để thuận tiện hơn trong việc thay đổi thuộc tính, bạn nên tạo 1 module và copy hàm sau:
![[Hình: startup.jpg]](http://i39.photobucket.com/albums/e193/duytuan2002/Access/startup.jpg)
Mã:Function ChangeProperty(strPropName, varPropType, varPropValue)
Dim dbs As Database, prp As Property
Const conPropNotFoundError = 3270
Set dbs = CurrentDb
On Error GoTo Change_XuLyLoi
dbs.Properties(strPropName) = varPropValue
ChangeProperty = True
Change_KetThuc:
Exit Function
Change_XuLyLoi:
'Thuộc tính không thấy
If Err = conPropNotFoundError Then
Set prp = dbs.CreateProperty(strPropName, _
varPropType, varPropValue)
dbs.Properties.Append prp
Resume Next
Else
'Không có thuộc tính đó
ChangeProperty = False
Resume Change_KetThuc
End If
End Function
Và dưới đây là tập hợp các thuộc tính trong (ngoài) form Startup mà bạn có thể gọi bất cứ đâu. Sau khi gọi, nó sẽ có hiệu lực từ lần mở chương trình kế tiếp:
Mã:Sub SercurityDB(locker As Boolean)
' Gọi đoạn module này ở form lock hay chỗ nào bạn thích.
'SecurityDB True ( False)
' Thuộc tính nào không cần dùng, abn5 chỉ việc cho dấu nháy (') đằng trước là được
''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
' Đổi tên Tiêu đề ứng dụng
ChangeProperty "Apptitle", dbText," Tên Tiêu Đề"
' Đặt lại Form gọi khi mở chương trình
ChangeProperty "StartupForm", dbText, "MainForm"
' Cho nhìn thấy Khung Database hay không
ChangeProperty "StartupShowDBWindow", dbBoolean, locker
'Cho nhìn thấy thanh Status hay không
ChangeProperty "StartupShowStatusBar", dbBoolean, True
' Cho phép hiển thị thanh design hay không
ChangeProperty "AllowBuiltinToolbars", dbBoolean, locker
' Cho phép thêm bớt 1 item vào các thanh công cụ hay không
ChangeProperty "AllowToolbarChanges", dbBoolean, locker
' Cho phép hiện thanh bar khi nhấn chuột phải hay không
ChangeProperty "AllowShortcutMenus", dbBoolean, locker
' Cho phép hiện toàn bộ thanh menu hay không
ChangeProperty "AllowFullMenus", dbBoolean, locker
'Cho phép ngừng chương trình lại bằng phím Ctrl+ Break khi đang run hay không
ChangeProperty "AllowBreakIntoCode", dbBoolean, locker
' Vô hiệu hóa phím đặc biệt như F11
ChangeProperty "AllowSpecialKeys", dbBoolean, locker
' Vô hiệu hóa phím shift
ChangeProperty "AllowBypassKey", dbBoolean, locker
'Cho phép design/ sửa thuộc tính form/ report khi đang mở hay không.
ChangeProperty "AllowDesignChanges", dbBoolean, locker
' Set lại đường dẫn Icon cùng với nơi lưu chương trình
ChangeProperty "AppIcon", dbText, Access.CurrentProject.Path & "Icon1.ico"
' Gắn lại tên menubar tự tạo:
Application.MenuBar = "My menubar"
'Gắn lại tên shotcuts menubar ( tạo bằng macro)
Application.ShotcutMenuBar = "My ShotCut Menubar"
End Sub
Các đoạn mình tô màu xanh đậm, các bạn có thể thay đổi cho phù hợp với chương trình của bạn.
Các thuộc tính không cần thay đổi, bạn có thể xóa bỏ hoặc đặt dấu nháy đơn (') đằng trước. -
RE: Thuộc tính Startup MS Access toàn tập với VBA
hungle2006 > 18-04-16, 04:32 PM
Noname ơi, mình muốn không cho design form từ menu chuột phải thì phải gắn code vào đâu nhỉ, mình gà access lắm