• Tùy chọn
• Đăng nhập
• Đăng ký
• Xem như trên Máy tính
• Accelerated Mobile Pages Theme

In nhiều record cùng lúc

• Trang chủ

  • Thủ Thuật Access
  • Access Cơ Bản
  • Macro
  • In nhiều record cùng lúc
• In nhiều record cùng lúc

• RE: In nhiều record cùng lúc

  binhhoajp1052 > 06-01-24, 09:16 AM

  Báo lỗi gì đó liên quan đến Transdate bác @ongke0711 ơi, để mình check lại thử
  mà mình ko biết
  -Up hình như bác @ongke0711 
  -Đổi tên tiêu đề 
  ai chỉ với 

• RE: In nhiều record cùng lúc

  binhhoajp1052 > 06-01-24, 11:52 AM

  Ok lỗi Transdate là do khác định dạng về ngày, máy mình là dấu chấm, phải đổi thành dấu / mới được
  nhưng còn lỗi là: trong ngày 4/1/2023 có 2 record với nội dung lần lượt là Xin chào và Mọi người
  thì khi chọn in toàn bộ record trong ngày đó nó vẫn ra 2 record, nhưng cùng một nội dung là Xin chào
  mình đọc tới đọc lui cũng ko biết sửa chỗ nào, nhờ bác @ongke0711 chỉ điểm
  mình có chụp ảnh đây: https://www.mediafire.com/view/bhy22kd78...5.PNG/file

• RE: In nhiều record cùng lúc

  ongke0711 > 06-01-24, 03:06 PM

  (06-01-24, 11:52 AM)binhhoajp1052 Đã viết: Ok lỗi Transdate là do khác định dạng về ngày, máy mình là dấu chấm, phải đổi thành dấu / mới được
  nhưng còn lỗi là: trong ngày 4/1/2023 có 2 record với nội dung lần lượt là Xin chào và Mọi người
  thì khi chọn in toàn bộ record trong ngày đó nó vẫn ra 2 record, nhưng cùng một nội dung là Xin chào
  mình đọc tới đọc lui cũng ko biết sửa chỗ nào, nhờ bác @ongke0711 chỉ điểm
  mình có chụp ảnh đây: https://www.mediafire.com/view/bhy22kd78...5.PNG/file

  
  Bạn thay code trong file bằng code mới dưới đây:
  
  

  Mã:

  Option Compare Database
Option Explicit

Private Sub Form_Load()
    Call fraPrintOptions_AfterUpdate
End Sub

Private Sub fraPrintOptions_AfterUpdate()
    Select Case Me.fraPrintOptions.Value
    Case 1
        Me.cboNgay.Enabled = False
    Case 2
        Me.cboNgay.Enabled = True
    End Select
End Sub

Private Sub cmdXuatPDF_Click()
    Select Case Me.fraPrintOptions.Value
    Case 1
        XuatPDF Me.txtID, Nz(Me.Particular, "")
    Case 2
        If IsNull(Me.cboNgay) Then
            MsgBox "Ban chua chon [Ngày] de in.", vbExclamation, "Thông báo"
            Exit Sub
        End If
        Dim rs As DAO.Recordset
        Set rs = CurrentDb.OpenRecordset("SELECT ID, Particular FROM Table1 WHERE [TransDate] = #" & Format(Me.cboNgay, "mm/dd/yyyy") & "#")
        rs.MoveFirst
        Do Until rs.EOF
            XuatPDF rs!ID, Nz(rs!Particular, "")
            rs.MoveNext
        Loop
        rs.Close
        Set rs = Nothing
    End Select

    MsgBox "Da xuat Report sang file PDF thanh cong.", vbInformation, "Thông báo"
   
End Sub

Sub XuatPDF(vID As Variant, sParticular As String)
    Dim sRptName As String, sFileName As String, sFilePath As String, sFolderPath As String
   
    sFolderPath = "C:\Temp"
    sFileName = IIf(Len(sParticular & "") = 0, Format(Date, "yyyymmdd"), sParticular)
    sRptName = "Report1"
    sFilePath = sFolderPath & "\" & sFileName & "_" & vID & ".pdf"
   
    DoCmd.OpenReport sRptName, acViewReport, , "[ID] = " & vID, acHidden
    DoCmd.OutputTo acOutputReport, sRptName, acFormatPDF, sFilePath
    DoCmd.Close acReport, sRptName
End Sub

• RE: In nhiều record cùng lúc

  binhhoajp1052 > 06-01-24, 04:12 PM

  OK quá @ongke0711 ơi, cảm ơn bạn thật nhiều nhé
• Bài trước Bài tiếp