• Tùy chọn
• Đăng nhập
• Đăng ký
• Xem như trên Máy tính
• Accelerated Mobile Pages Theme

Tăng tốc độ truy cập dữ liệu từ Linked Table

• Trang chủ

  • Thủ Thuật Access
  • Access Nâng Cao
  • Thư viện thủ thuật
  • [Thủ Thuật] Tăng tốc độ truy cập dữ liệu từ Linked Table
• Tăng tốc độ truy cập dữ liệu từ Linked Table

• Tăng tốc độ truy cập dữ liệu từ Linked Table

  ongke0711 > 23-09-19, 04:09 PM

  Việc tách ứng dụng Access (Split database) ra thành 2 file Front End và Back End (chỉ lưu table) có rất nhiều điểm thuận lợi như: dễ bảo trì, sửa chữa code, backup CSDL và quan trọng là có thể copy cho nhiều người dùng file FE để cùng truy cập đến dữ liệu trung tâm là file BE.
  
  
  
  Tuy nhiên việc Split database này cũng có ảnh hưởng đến tốc độ xử lý truy cập dữ liệu từ Linked Table có chậm hơn so với ứng dụng Access đứng một mình nó. Đặc biệt nếu file BE có đặt mật khẩu thì tốc độ càng ảnh hưởng thấy rõ.
  Nguyên nhân gây chậm trong trong ứng dụng dùng Linked Table là: Việc tạo/ xoá các "lock file" (.ldb, .laccdb). Khi có Table được mở thì file BE sẽ tạo ra một "lock file" và khi đóng Table nó sẽ xoá file lock này. Việc tạo/ xoá này cũng làm mất thời gian. Hơn nữa trong môi trường nhiều ngừoi dùng, khi người dùng thứ 2 kết nối, mở linked table thì BE sẽ cố gắng xoá file lock cũ nhưng không được vì thời điểm đó người dùng 1 đang mở table đó. Access sẽ tự động chạy thủ tục xoá này khoảng 15 lần trước khi bỏ cuộc.
  
  Do đó để tránh việc tự động tạo/ xoá lock file, thì thủ thuật là tạo một kết nối liên tục đến linked table cho đến khi thoát ứng dụng. Việc kết nối liên tục này không ảnh hưởng gì đến môi trường đa người dùng.
  Tạo kết nối tới linked database có nhiều cách như: 
  - Mở 1 linked table.
  - Mở database dữ liệu.
  - Dùng biến toàn cục Recordset để duy trì mở linked table.
  - Dùng code vba để mở kết nối tới tất cả các database mà bạn linked table
  - ...
  
  Ở đây tôi demo 2 cách: 1 cách hết sức đơn giản là dùng Form (frmKeepOpenConn) mở linked table và cách kia thì dùng code mở database. Tôi thì luôn dùng cách 1 cho đơn giản.   
  
  Cách 1: (dùng cho trường hợp chỉ kết nối tới 1 database)
  - Tạo 1 table có chừng 1 field, 1 dòng dữ liệu cũng được trong file BE và tạo linked table tới file FE.
  - Tạo 1 Form có Record Source là Table tạm đã tạo ở trên. Form này sẽ được chạy nền ở chế độ Hidden khi ứng dụng FE của bạn khởi chạy.
  - Khi ứng dụng FE chạy, các bạn thường chạy 1 form Splash để giới thiệu hoặc form Login, frmMain... Sử dụng mấy form này để khởi chạy frmKeepOpenConn.
  
  

  Mã PHP:

  Private Sub Form_Open(Cancel As Integer)
    DoCmd.OpenForm "frmKeepOpenConn", acNormal, , , , acHidden
End Sub 


  
  
  
  
  Một cách khác là tạo biến đối tượng toàn cục cho Recordset. Khi frmMain khởi chạy sẽ tạo và gán biến này. (Form khởi chạy là tuỳ theo ứng dụng của bạn)
  
  

  Mã PHP:

  Public rsKeepOpenConn As DAO.Recordset

Private Sub Form_Close()
    rsKeepOpenConn.Close
    Set rsKeepOpenConn = Nothing
End Sub

Private Sub Form_Open(Cancel As Integer)
    Set rsKeepOpenConn = CurrentDb.OpenRecordset("tblKeepConn")
End Sub 


  
  Cách 2:
  Dùng code VBA để tạo kết nối tới các database mà bạn linked table (có nhiều ứng dụng link tới vài database). Cách này bạn phải biết đường dẫn của file database back end.
  
  

  Mã PHP:

  Sub OpenAllDatabases(pfInit As Boolean)
' Mo ket noi toi tat ca các Database dùng trong linked table, giu ket noi den khi dóng chuong trinh .
' pfInit:  TRUE - Mo ket noi    (Goi khi khoi chay chuong trình)
'          FALSE - Dóng ket noi  (Goi khi thoat chuong trình)
'Nguon: Total Visual SourceBook
'----------------------------------------------------------------------


    ' Khai bao tong so BE database kêt noi
    Const cintMaximumDatabases As Integer = 2

    Dim X As Integer, i As Integer
    Dim strName As String
    Dim strMsg As String

    Dim rsDBName As DAO.Recordset
    Dim SourcePath(cintMaximumDatabases) As Variant

    'Lay toan bo duong dan file database BE luu vào mang
    Set rsDBName = DBEngine(0)(0).OpenRecordset("tblLinkedDBName", dbOpenDynaset)
    If rsDBName.EOF And rsDBName.BOF Then
        MsgBox "Khong tim thay duong dan file database ket noi", vbCritical, "Thông báo"
        Exit Sub
    End If
    rsDBName.MoveFirst
    i = 0
    Do Until rsDBName.EOF
        SourcePath(i) = CurrentProject.Path & "\Data\" & rsDBName!DBName
        i = i + 1
        rsDBName.MoveNext
    Loop

    ' Liet ke toan bo databases ket noi vào mang
    Static dbsOpen() As DAO.Database

    If pfInit Then
        ReDim dbsOpen(1 To cintMaximumDatabases)
        For X = 1 To cintMaximumDatabases
            ' Duyet tung databases
            strName = SourcePath(X - 1)
            strMsg = ""

            On Error Resume Next
            Set dbsOpen(X) = OpenDatabase(strName, False, False, ";PWD=123456")
            If Err.Number > 0 Then
                strMsg = "Loi ket noi database: " & strName & vbCrLf & _
                        "Kiem tra lai duong dan file." & vbCrLf & _
                        "Error: " & Err.Description & " (" & Err.Number & ")"
            End If

            On Error GoTo 0
            If strMsg <> "" Then
                MsgBox strMsg
                Exit For
            End If
        Next X
        'MsgBox "Mo Ket noi xong."
    Else
        On Error Resume Next
        For X = 1 To cintMaximumDatabases
            dbsOpen(X).Close
        Next X
    End If
End Sub 


  
  
  Link demo: https://drive.google.com/open?id=1-ronx4...lkr2bzdcKa

• RE: Tăng tốc độ truy cập dữ liệu từ Linked Table

  HoangHoa > 23-09-19, 04:33 PM

  Hay quá anh @Ongke0711 ơi, Chúc anh SỨC KHỎE để có thể giúp cho mọi người.

• RE: Tăng tốc độ truy cập dữ liệu từ Linked Table

  Linh lê > 12-05-21, 04:17 PM

  Cảm ơn chủ thớt. Thủ thuật hay.
• Bài trước Bài tiếp