• Tùy chọn
• Đăng nhập
• Đăng ký
• Xem như trên Máy tính
• Accelerated Mobile Pages Theme

Lỗi xảy ra khi thực thi DAO Connection?

• Trang chủ

  • Thủ Thuật Access
  • Access Cơ Bản
  • Thành viên giúp nhau
  • [Hỏi] Lỗi xảy ra khi thực thi DAO Connection?
• Lỗi xảy ra khi thực thi DAO Connection?

• Lỗi xảy ra khi thực thi DAO Connection?

  shevchenki > 08-12-17, 12:32 AM

  Chuyện là em xuất dữ liệu từ một Query qua một File Excel bên ngoài và em dùng ADO Connection.
  Em hay dùng DAO là chính nên lỗi về ADO em cũng ko rõ nên hỏi.
  Với Query mà em có gắn Parameter là dạng Form![FormName]![BoxName] thì khi em chạy thì em bị lỗi như dưới:
  RunTime Error - 2147217900 Invalid SQL Statement; expected 'DELETE' 'INSERT'...
  
  Với Query mà em gắn Parameter với điều kiệu trực tiếp như kiểu Is Null hay "Một giá trị bất kỳ" thì vẫn chạy được, nhưng cứ gắn dạng biến theo Form thì lại bị lỗi này. Em có định dạng cho Form![FormName]![BoxName]  trong Parameter của Query nhưng vẫn kết quả như vậy.
  
  'Trigger
  
  Private Sub BntOuputQuery_Click()
  
      Const stPath As String = "C:\FolderName"
      Const stXLName As String = "\FileName.xlsm"
      Const stQryName As String = "QueryName" 'Query có sự dụng Parameter dạng Form![FormName]![BoxName]
      Const stSheet As String = "SheetNameOfExcel"
      Const stRng As String = "A4" 'Paste To Cell
  
      Call OpenExcel(stPath, stXLName, stQryName, stSheet, stRng, "B1")
  End Sub
  
  'To Open and Paste On Excel
  
  Public Sub OpenExcel(ByVal stPath As String, ByVal stXLName As String, ByVal stQryName As String, ByVal stSheet As String, ByVal stRng As String, ByVal timeRng As String)
  
      Dim cnt As ADODB.Connection
      Dim rst As ADODB.Recordset
      Dim xls As Excel.Application
      Dim wkb As Excel.Workbook
  
      Set cnt = CurrentProject.Connection
      Set rst = New ADODB.Recordset
      rst.Open stQryName, cnt 'Lỗi xảy ra ở đây
  
      Set xls = CreateObject("Excel.Application")
      xls.Workbooks.Add template:=stPath & stXLName
      Set wkb = xls.Workbooks(1)
  
      With wkb.Worksheets(stSheet)
          .Range(stRng).CopyFromRecordset Data:=rst
          .Range(timeRng).Value = Now
      End With
  
      xls.Visible = True
  
      rst.Close
      cnt.Close
      Set rst = Nothing
      Set cnt = Nothing
  
  End Sub
  
  Mong mọi người cho e lời khuyên
  EM CÁM ƠN!

• RE: Cả nhà giúp em giải quyết vấn đề lỗi này với!

  maidinhdan > 08-12-17, 01:15 AM

  Thông tin chú đưa không đủ để trả lời đâu.
  
  Post cả đoạn code liên quan đến cái hàm ADO lên đây
  
  * Bài viết sẽ bị xoá trong 24h tới nếu không chỉnh lại tiêu đề

• RE: Lỗi xảy ra khi thực thi DAO Connection?

  hieuvn > 08-12-17, 04:26 PM

  chỉ cần post query lên thôi không cần post code xuất ra excel làm gì.
  parameter cho SqlServer thì để quote là ' ' thay vì " " như trong Access nhé.
  Have fun

• RE: Lỗi xảy ra khi thực thi DAO Connection?

  shevchenki > 08-12-17, 06:47 PM

  Mình giải thích hơi kém nên bạn thông cảm
  Nhưng thật là bực mình khi gặp cái lỗi như vậy đấy
  Để tối mình làm cái mô phỏng cho dễ hiểu. Đêm qua đêm quá rồi mà hnay đi làm nên mình chưa có làm được

• RE: Lỗi xảy ra khi thực thi DAO Connection?

  maidinhdan > 08-12-17, 07:04 PM

  (08-12-17, 12:32 AM)shevchenki Đã viết: Chuyện là em xuất dữ liệu từ một Query qua một File Excel bên ngoài và em dùng ADO Connection.
  Em hay dùng DAO là chính nên lỗi về ADO em cũng ko rõ nên hỏi.
  Với Query mà em có gắn Parameter là dạng Form![FormName]![BoxName] thì khi em chạy thì em bị lỗi như dưới:
  RunTime Error - 2147217900 Invalid SQL Statement; expected 'DELETE' 'INSERT'...
  
  Với Query mà em gắn Parameter với điều kiệu trực tiếp như kiểu Is Null hay "Một giá trị bất kỳ" thì vẫn chạy được, nhưng cứ gắn dạng biến theo Form thì lại bị lỗi này. Em có định dạng cho Form![FormName]![BoxName]  trong Parameter của Query nhưng vẫn kết quả như vậy.
  
  
      Const stQryName As String = "QueryName" 'Query có sự dụng Parameter dạng Form![FormName]![BoxName]
  
  
  
        rst.Open stQryName, cnt 'Lỗi xảy ra ở đây

  
  Bạn phải truyên vào là 1 chuỗi sql, không thể truyền bằng tên table hay tên query nên nó lỗi là phải.

• RE: Lỗi xảy ra khi thực thi DAO Connection?

  MTNQ > 09-12-17, 12:47 PM

  (08-12-17, 12:32 AM)shevchenki Đã viết: Chuyện là em xuất dữ liệu từ một Query qua một File Excel bên ngoài và em dùng ADO Connection.
  Em hay dùng DAO là chính nên lỗi về ADO em cũng ko rõ nên hỏi.
  Với Query mà em có gắn Parameter là dạng Form![FormName]![BoxName] thì khi em chạy thì em bị lỗi như dưới:
  RunTime Error - 2147217900 Invalid SQL Statement; expected 'DELETE' 'INSERT'...
  
  Với Query mà em gắn Parameter với điều kiệu trực tiếp như kiểu Is Null hay "Một giá trị bất kỳ" thì vẫn chạy được, nhưng cứ gắn dạng biến theo Form thì lại bị lỗi này. Em có định dạng cho Form![FormName]![BoxName]  trong Parameter của Query nhưng vẫn kết quả như vậy.
  
  'Trigger
  
  Private Sub BntOuputQuery_Click()
  
      Const stPath As String = "C:\FolderName"
      Const stXLName As String = "\FileName.xlsm"
      Const stQryName As String = "QueryName" 'Query có sự dụng Parameter dạng Form![FormName]![BoxName]
      Const stSheet As String = "SheetNameOfExcel"
      Const stRng As String = "A4" 'Paste To Cell
  
      Call OpenExcel(stPath, stXLName, stQryName, stSheet, stRng, "B1")
  End Sub
  
  'To Open and Paste On Excel
  
  Public Sub OpenExcel(ByVal stPath As String, ByVal stXLName As String, ByVal stQryName As String, ByVal stSheet As String, ByVal stRng As String, ByVal timeRng As String)
  
      Dim cnt As ADODB.Connection
      Dim rst As ADODB.Recordset
      Dim xls As Excel.Application
      Dim wkb As Excel.Workbook
  
      Set cnt = CurrentProject.Connection
      Set rst = New ADODB.Recordset
      rst.Open stQryName, cnt 'Lỗi xảy ra ở đây
  
      Set xls = CreateObject("Excel.Application")
      xls.Workbooks.Add template:=stPath & stXLName
      Set wkb = xls.Workbooks(1)
  
      With wkb.Worksheets(stSheet)
          .Range(stRng).CopyFromRecordset Data:=rst
          .Range(timeRng).Value = Now
      End With
  
      xls.Visible = True
  
      rst.Close
      cnt.Close
      Set rst = Nothing
      Set cnt = Nothing
  
  End Sub
  
  Mong mọi người cho e lời khuyên
  EM CÁM ƠN!

  
  Có 2 phương án:
  
  1/phương án 1:
  Thay điều kiện Form![FormName]![BoxName] trong query bằng  một hàm tự tạo:
   VD : tại dòng điều kiện của query bạn gõ vào =fnMsnv() vớ hàm  fnMsnv() tương tự như sau:
  

  Mã:

  Public Function fnMsnv()
   Dim m
   m = [Forms]![Form1]![cbo_manv]
   fnMsnv = m
End Function

  
  
  1/Phương án 2:
  Sửa thủ tục OpenExcel lại như sau
  
  
  

  Mã:

  Public Sub OpenExcel(ByVal stPath As String, ByVal stXLName As String, ByVal stQryName As String, ByVal stSheet As String, ByVal stRng As String, ByVal timeRng As String)

   Dim cmd As New ADODB.Command
   Dim prm As ADODB.Parameter
   Dim rst As New ADODB.Recordset
   Dim xls As Excel.Application
   Dim wkb As Excel.Workbook
   
   On Error GoTo Err_handler
   
   Set cmd.ActiveConnection = CurrentProject.Connection
   
   cmd.CommandText = "SELECT * FROM " & stQryName
   cmd.Parameters.Refresh
   For Each prm In cmd.Parameters
       prm.Value = Eval(prm.Name)
   Next
   rst.Open cmd, , adOpenForwardOnly, adLockReadOnly
   
   If rst Is Nothing Or rst.EOF Then
       MsgBox "Khong co du lieu de xuat!"
       GoTo Err_Exit
   End If
   
   Set xls = CreateObject("Excel.Application")
   xls.Workbooks.Add template:=stPath & stXLName
   Set wkb = xls.Workbooks(1)
   
   With wkb.Worksheets(stSheet)
       .Range(stRng).CopyFromRecordset Data:=rst
       .Range(timeRng).Value = Now
   End With

   xls.Visible = True

   rst.Close
   
   
Err_Exit:
   Set rst = Nothing
   Set cmd = Nothing
   Set prm = Nothing
   Exit Sub
 
Err_handler:
   MsgBox Err.Description, , "OpenExcel Error: " & Err.Number
   Resume Err_Exit
   
End Sub
• Bài trước Bài tiếp