• Tùy chọn
• Đăng nhập
• Đăng ký
• Xem như trên Máy tính
• Accelerated Mobile Pages Theme

Cập nhật người dùng lên form hiển thị

• Trang chủ

  • Thủ Thuật Access
  • Access Cơ Bản
  • Forms
  • Cập nhật người dùng lên form hiển thị
• Cập nhật người dùng lên form hiển thị

• Cập nhật người dùng lên form hiển thị

  kutieu2016 > 15-04-17, 07:46 AM

  Em đang tạo form cập nhật người dùng mới và thay đổi thông tin của người sử dụng. Cụ thể như sau: Khi em mở form frmNGUOIDUNG ra và click đúp chuột vào từng người dùng của lstDanhSach thì nó sẽ hiện form frmNGUOIDUNG_sua tương ứng. Khi form frmNGUOIDUNG_sửa hiển thị thì nó sẽ cập nhật đúng thông tin người dùng đã được click đúp vào. và khi này mình sẽ thông tin của người dùng này và lưu là xong.
  Cám ơn mọi người nhiều!
  Link: http://www.mediafire.com/file/17ec9y6lyi...ngNhap.rar

• RE: Cập nhật người dùng lên form hiển thị

  ongke0711 > 15-04-17, 03:30 PM

  Chia sẻ bạn mấy cái hàm tôi hay dùng để load records lên cho các Unbound Form. Thường tôi sẽ dùng Unbound form cho trường hợp này để đơn giản bớt việc bẫy lỗi khi lưu, sửa các record.
  - Để chạy được các hàm trong bài, bạn phải theo qui ước đặt tên các controls trong form. Phải đặt tên là: txt (hoặc cbo, chk) + tên Field trong table (làm Record Source cho form).
  VD: tblNGUOIDUNG của bạn có các field: user, pass, hoten… => đặt tên control tương ứng trong form sẽ là: txtuser, txtpass, txthoten…
  - Sử dụng cùng 1 Form frmNGUOIDUNG_Sua cho cả việc Sửa hoặc Thêm mới người dùng.
  - Bạn chú ý tham số OpenArgs khi mở form.
  - Code các Function: GetRecord, UpdateRecord, AddRecord
  

  Mã PHP:

  Option Explicit
[/font]

Public Function GetRecord(rst As DAO.Recordset, frm As Form)
   Dim fld As Field
   Dim ctl As Control
   For Each fld In rst.Fields
       For Each ctl In frm.Controls
           If ctl.Name = "txt" & fld.Name Or ctl.Name = "cbo" & fld.Name Or ctl.Name = "chk" & fld.Name Then
               ctl = rst.Fields("" & fld.Name & "").Value
           ElseIf ctl.Name = "img" & fld.Name Then
               If Not IsNull(rst.Fields("" & fld.Name & "").Value) Then
               'On Error Resume Next'
               ctl.Picture = CStr(rst.Fields("" & fld.Name & "").Value)
               End If
           End If
       Next
   Next
End Function

Public Function AddRecord(rst As DAO.Recordset, frm As Form)
   Dim fld As Field
   Dim ctl As Control
   rst.AddNew
   For Each fld In rst.Fields
       For Each ctl In frm.Controls
           If ctl.Name = "txt" & fld.Name Or ctl.Name = "cbo" & fld.Name Or ctl.Name = "chk" & fld.Name Then
               rst.Fields("" & fld.Name & "").Value = ctl
           End If
       Next
   Next
   rst.Update
End Function

Public Function UpdateRecord(rst As DAO.Recordset, frm As Form)
   Dim fld As Field
   Dim ctl As Control
   rst.Edit
   For Each fld In rst.Fields
       For Each ctl In frm.Controls
           If ctl.Name = "txt" & fld.Name Or ctl.Name = "cbo" & fld.Name Or ctl.Name = "chk" & fld.Name Then
               rst.Fields("" & fld.Name & "").Value = ctl
           End If
       Next
   Next
   rst.Update
End Function

Public Sub ClearRecord(frm As Form)
   Dim ctl As Control
   For Each ctl In frm.Controls
       If ctl.Tag Like "no" Then
           'do nothing'
       Else
           Select Case ctl.ControlType
               Case acTextBox, acComboBox, acCheckBox
                   ctl.Value = ""
               Case acImage
                   ctl.Picture = ""
               Case Else
                   'do nothing'
           End Select
       End If
   Next
[font=Tahoma]End Sub 


  
  
  Link file demo: http://www.mediafire.com/file/c43c3f255b...8v1%29.mdb

• RE: Cập nhật người dùng lên form hiển thị

  kutieu2016 > 15-04-17, 09:13 PM

  Giải pháp này của anh hay quá! 
  Cám ơn anh nhiều!
• Bài trước Bài tiếp