Tùy chọn
Sửa tiêu đề Database thành Tiếng Việt.
- Sửa tiêu đề Database thành Tiếng Việt.
-
Sửa tiêu đề Database thành Tiếng Việt.
Minh Tiên > 09-10-13, 08:59 AM
tmtien261 có một vấn đề nhờ các Pro chỉ giáo !
- Cách sửa được "Tên tiêu đề Database trong Access" thành tiếng Việt. (Phần khoanh tròn hình dưới).
tmtien261 thấy một số chương trình Acc họ sửa được nhưng không biết cách nào sửa.
[img]![[Hình: Hinhve_Hoi.PNG]](https://lh4.googleusercontent.com/-zDLN7uweA6Q/UlSpyjSB2nI/AAAAAAAABTY/LbWoFUKQQ-o/Hinhve_Hoi.PNG)
[/img]
Xin các pro chỉ giúp. Cảm ơn nhiều. -
RE: Sửa tiêu đề Database thành Tiếng Việt.
khải nguyên > 09-10-13, 11:20 AM
Làm theo như hình trong Link này - Access 2007 chắc cũng giống như 2010 :
http://www.mediafire.com/download/5hurjb...t_2003.doc
Chúc thành công
Khải Nguyên -
RE: Sửa tiêu đề Database thành Tiếng Việt.
quanghoasla > 10-10-13, 06:47 PM
Bạn vào tools/startup/sửa nội dung ở phần application title -
RE: Sửa tiêu đề Database thành Tiếng Việt.
quanghoasla > 10-10-13, 07:35 PM
hiiiiiiii officce 2007 chứ bồ -
RE: Sửa tiêu đề Database thành Tiếng Việt.
paulsteigel > 10-10-13, 10:31 PM
Vì tiêu đề của 1 ứng dụng Access là 1 loại thuộc tính của nó (ngay cả việc chặn bấm phím Shift hoặc các loại khác ...vv cũng là thuộc tính). Vì thế ta có thể tạo thuộc tính cho nó. Bình thường nhiều thuộc tính chưa được khởi tạo vì thế khi muốn tương tác ta phải tạo nó trước (tất nhiên tạo rồi thì xóa cũng được).
Cách sau đây ứng dụng VBA để tạo thuộc tính và tất nhiên bạn có thể làm nhiều thứ với cái này.
Nếu mọi người quan tâm, tôi sẽ đưa thêm nhiều thuộc tính khác của ứng dụng Accesss.....Mã PHP:Sub SetAppTitle()
Dim AppProperty As Property, TieuDeUngDung As String
TieuDeUngDung = "Hello"
On Error GoTo ErrHandler
Debug.Print CurrentDb().Properties("AppTitle").Value
Exit Sub
ErrHandler:
Set AppProperty = CurrentDb().CreateProperty("AppTitle", 12, TieuDeUngDung)
CurrentDb().Properties.Append AppProperty
Resume 0
End Sub -
RE: Sửa tiêu đề Database thành Tiếng Việt.
Xuân Thanh > 12-10-13, 05:23 PM
(10-10-13, 10:31 PM)paulsteigel Đã viết: Vì tiêu đề của 1 ứng dụng Access là 1 loại thuộc tính của nó (ngay cả việc chặn bấm phím Shift hoặc các loại khác ...vv cũng là thuộc tính). Vì thế ta có thể tạo thuộc tính cho nó. Bình thường nhiều thuộc tính chưa được khởi tạo vì thế khi muốn tương tác ta phải tạo nó trước (tất nhiên tạo rồi thì xóa cũng được).
Cách sau đây ứng dụng VBA để tạo thuộc tính và tất nhiên bạn có thể làm nhiều thứ với cái này.
Nếu mọi người quan tâm, tôi sẽ đưa thêm nhiều thuộc tính khác của ứng dụng Accesss.....Mã PHP:Sub SetAppTitle()
Dim AppProperty As Property, TieuDeUngDung As String
TieuDeUngDung = "Hello"
On Error GoTo ErrHandler
Debug.Print CurrentDb().Properties("AppTitle").Value
Exit Sub
ErrHandler:
Set AppProperty = CurrentDb().CreateProperty("AppTitle", 12, TieuDeUngDung)
CurrentDb().Properties.Append AppProperty
Resume 0
End Sub
Anh N. có thời gian thì viết hẳn một chuyên đề riêng về cái AppProperty của Access này nhé
Thân mến -
RE: Sửa tiêu đề Database thành Tiếng Việt.
Minh Tiên > 12-10-13, 06:17 PM
Đúng đấy ! paulsteigel hãy làm hẳn một chuyên đề về "AppProperty" để chia sẽ cùng ACE.
Thanks! -
RE: Sửa tiêu đề Database thành Tiếng Việt.
paulsteigel > 15-10-13, 12:34 AM
Phần I: Giới thiệu chung về thuộc tính
1. Sơ lược về DAO
Cơ sở dữ liệu Access, về bản chất nó là một cách tổ chức dữ liệu. Để tương tác với số liệu người ta dùng các trình quản lý dữ liệu. Để tiện lợi, ta gọi đó là DataEngine.
Có nhiều loại DataEngine khác nhau trong đó cái ta hay dùng và quen dùng là DAO (đối tượng truy nhập dữ liệu) được hình thành từ lâu lắm rồi. Cái mới hơn ta hay gọi là ADO (ActiveX Data Objects), ADODB ...vv.
Hồi mới khai sinh ra DAO (1992) thì quả thật DAO có thể nói chỉ đơn thuần là một DataEngine, nhưng kể từ khi phiên bản DAO 3.1 ra đời thì nó đã mạnh mẽ hơn rất nhiều và được nhiều nhà phát triển gọi là Giao diện lập trình tương tác Hệ thống dữ liệu JET của Microsoft (tên hơi dài - đây là cách tôi gọi theo một số trang web trên mạng, từ tiếng Anh là "The Programmatic Interface to Microsoft Jet"). Jet là một DataEngine được thiết kế để sử dụng trong Access và VB cũng như các ứng dụng VBA.
Với sự thay đổi này, DAO được bổ sung một lớp trung gian cho phép người lập trình có thể can thiệp nhiều hơn vào cơ sở dữ liệu, kiểm soát mạnh hơn các tổ chức số liệu.
2. Thuộc tính
Riêng với CSDL Access, DAO có thể quản lý được cách ứng dụng Access thực thi thông qua việc bổ sung thêm vào CSDL một lớp thông tin liên quan đến CSDL và cho phép hay không cho phép Ứng dụng Access thực hiện một số nhiệm vụ cụ thể nào đó cũng như để lưu thông tin mà người dùng muốn đưa vào CSDL bên ngoài cấu trúc các loại bảng thông thường.
Những thông tin như vậy ta gọi là thuộc tính người dùng (Custom Property). Những thuộc tính này chỉ có thể tương tác được thông qua sử dụng bộ thư viện DAO mà thôi.
Những thông tin quy định cách vận hành ứng dụng Access được gọi là nhóm thuộc tính Vận hành (Database Operation Properties).
Khác với các thuộc tính cơ bản của cơ sở dữ liệu mà ta có thể gọi ra bất kỳ lúc nào như Name (tên), Path (đường dẫn) ... Các thuộc tính người dùng này không có sẵn trong Cơ sở dữ liệu. Muốn có chúng, ta phải tạo ra chúng, thêm vào kho thuộc tính và sau đó có thể thực hiện sửa thông số hoặc xóa thuộc tính (tôi sẽ nói trong các phần sau).
Ví dụ, ta có thể tạo ra các thuộc tính theo cách riêng ví dụ Banquyen, Chuoimahoa ...vv để lưu các thông tin nhạy cảm mà ta không muốn đưa vào cấu trúc bảng.
2.1. Thuộc tính Vận hành
Danh sách các thuộc tính vận hành của CSDL Access như dưới đây (các thuộc tính này sẽ được kiểm tra khi CSDL khởi động):
Tên thuộc tính Giải thích
AppTitle Tiêu đề CSDL/ Ứng dụng Access
AppIcon Đường dẫn biểu tượng của ứng dụng
StartupShowDBWindow Khi khởi động thì hiển thị cửa sổ CSDL
StartupShowStatusBar Khi khởi động thì hiển thị thanh trạng thái
AllowShortcutMenus Cho phép sử dụng phím tắt của Access
AllowFullMenus Cho phép sử dụng thực đơn đầy đủ của Access
AllowBuiltInToolbars Cho phép hiển thị thanh công cụ có sẵn của Access
AllowToolbarChanges Cho phép sửa đổi thanh công cụ có sẵn của Access
AllowBreakIntoCode Cho phép đột nhập vào mã nguồn (bằng phím Alt+F11 chẳng hạn)
AllowSpecialKeys Cho phép nhấn phím đặc biệt (ví dụ phím Shift)
Replicable ...
ReplicationConflictFunction ...
Tôi chỉ xin phép đưa giải thích sơ bộ như vậy, các bạn có thể tự tìm lấy cái gì thích hợp cho mình để ứng dụng trong các phần sau. Lưu ý là những thông tin này chỉ tương thích với Access 2003, 2002, 2000 thôi nhé, những phiên bản mới hơn thì chỉ một số thuộc tính có tác dụng như AllowBreakIntoCode, AllowSpecialKeys. Lý do là vì Access mới đã sử dụng nền tảng thiết kế mới mất rồi.
Khi thiết lập/thay đổi các thuộc tính này, bạn phải khởi động lại CSDL thì nó mới có tác dụng nhé.
Phần II: Tương tác với thuộc tính
Do thời gian có hạn, nên tôi chỉ xin phép lấy một số thủ tục có sẵn từ trên mạng về để chúng ta tiện làm quen.
1. Tạo thuộc tính
Tôi sử dụng hàm CreateDBStrProp
Cách dùng Call CreateDBStrProp([Tenthuoctinh],[Giatri],[Kieusolieu]), hoặc sử dụng biến số. Hàm trả về True nếu khởi tạo thành công và false nếu không tạo được.
Vậy nếu muốn cấm người dùng nhấn phím đặc biệt để truy cập CSDL thì ta chỉ cần gọi thủ tục này như sau;
MsgBox [b]CreateDBStrProp("AllowSpecialKeys", True, dbBoolean )[/b]
... Các bạn có thể làm tương tự với các thuộc tính khác trong danh sách ở phần trên.
Nếu tôi muốn tạo một chuỗi mã hóa CSDL cho các thủ tục liên quan thì có thể làm như thế này
Call CreateDBStrProp("Chuoimahoa", "ABCDEFXX0102", dbText)
2. Đọc thuộc tính
Tôi sử dụng hàm GetDBPropValue. Cách dùng như sau;
Biến số = GetDBPropValue([Tên thuộc tính]) hoặc dùng Debug.Print để in ra màn hình dòng lệnh (Immediate Windows của Access, bấm Ctrl+G tại cửa sổ soạn thảo VBA)
3. Xóa thuộc tính
Tôi sử dụng hàm DBPropDelete. Cách dùng như sau;
Call CreateDBStrProp([Tên thuộc tính]) hoặc như hướng dẫn ở trên...
4. Kết luận
Qua bài này các bạn có thấy được khả năng áp dụng của việc tạo ra các thuộc tính người dùng không? Tôi đoán là có và các bạn hãy thử xem nhé.
Xin chân thành cảm ơn.
Mã nguồn các thủ tục như đoạn dưới đây
Mã PHP:Option Compare Database
' Truoc khi muon su dung code nay, can phai tham chieu den bo thu vien DAO nhe
'(thuong la DAO 3.6 tro len)
'---------------------------------------------------------------------------------------
' Thu tuc : CreateDBStrProp
' Muc dich : Tao thuoc tinh kieu chuoi dbText (string)
' Cach dung : CreateDBStrProp([Tenthuoctinh],[Giatri],[Kieusolieu])
' Tham so : strPropName As String-Ten thuoc tinh
' : strPropValue As String-Gia tri thuoc tinh can thiet lap
'---------------------------------------------------------------------------------------
Function CreateDBStrProp(strPropName As String, strPropValue As Variant, dbPropertyType As DAO.DataTypeEnum) As Boolean
On Error GoTo Err_CreateDBStrProp
Dim db As DAO.Database
Dim prp As Property
Set db = DBEngine(0)(0)
' Kiem tra xem thuoc tinh co ton tai khong de tranh gay loi
If ExistsDBProperty(strPropName) = False Then
Set prp = db.CreateProperty(strPropName, dbPropertyType, strPropValue)
db.Properties.Append prp
Else
Set prp = db.Properties(strPropName)
prp.Value = strPropValue
MsgBox "Thuoc tinh " & strPropName & " da ton tai" _
& vbCrLf & vbCrLf & "Da thiet lap xong gia tri cua thuoc tinh.", vbExclamation
End If
CreateDBStrProp = True
Exit_CreateDBStrProp:
Set prp = Nothing
Set db = Nothing
Exit Function
Err_CreateDBStrProp:
CreateDBStrProp = False
MsgBox "Co loi so " & Err.Number & " (" & Err.Description & ")" & " trong thu tuc CreateDBStrProp"
Resume Exit_CreateDBStrProp
End Function
'---------------------------------------------------------------------------------------
' Thu tuc : GetDBPropValue
' Muc dich : Doc thong tin thuoc tinh và tra ve gia tri da duoc thiet lap
' Cach dung : GetDBPropValue([Tenthuoctinh])
' Tham so : strPropName As String-Ten thuoc tinh
'---------------------------------------------------------------------------------------
Function GetDBPropValue(strPropName As String) As Variant
On Error GoTo Err_GetDBPropValue
Dim db As DAO.Database
Dim prp As Property
Set db = DBEngine(0)(0)
If ExistsDBProperty(strPropName) = False Then
MsgBox "DBProperty """ & strPropName & """ Khong ton tai.", vbExclamation
Else
Set prp = db.Properties(strPropName)
GetDBPropValue = prp.Value
Debug.Print GetDBPropValue
End If
Exit_GetDBPropValue:
Set prp = Nothing
Set db = Nothing
Exit Function
Err_GetDBPropValue:
MsgBox "Error " & Err.Number & " (" & Err.Description & ")" & _
" In procedure GetDBPropValue"
Resume Exit_GetDBPropValue
End Function
'---------------------------------------------------------------------------------------
' Thu tuc : DBPropDelete
' Muc dich : Xoa mot thuoc tinh do nguoi dung dinh nghia. Cac thuoc tinh co dinh khong
' : the xoa duoc. Thong bao loi se hien thi neu co gang lam the
' Cachdung : DBPropDelete([Tenthuoctinh])
' Tham so : strPropName As String-Ten thuoc tinh can xoa
'---------------------------------------------------------------------------------------
Function DBPropDelete(strPropName As String) As Boolean
On Error GoTo Err_DBPropDelete
Dim db As DAO.Database
Set db = DBEngine(0)(0)
If ExistsDBProperty(strPropName) = True Then
db.Properties.Delete strPropName
Else
MsgBox "Thuoc tinh nay khong ton tai.", vbExclamation
DBPropDelete = False
GoTo Exit_DBPropDelete
End If
If ExistsDBProperty(strPropName) = False Then
DBPropDelete = True
Else
DBPropDelete = False
End If
Exit_DBPropDelete:
Set db = Nothing
Exit Function
Err_DBPropDelete:
Debug.Print (Err.Description & " " & Err.Number & " trong thu tuc DBPropDelete")
If Err.Number = 3384 Then
MsgBox "Co loi xay ra." & vbCrLf & vbCrLf & _
"Khong the xoa thuoc tinh co san cua CSDL" _
, vbExclamation, "Canh bao loi..."
End If
Resume Exit_DBPropDelete
End Function
'---------------------------------------------------------------------------------------
' Thu tuc : ExistsDBProperty
' Muc dich : Kiem tra xem thuoc tinh cua CSDL co ton tai hay khong?
' Tham so : strPropName As String-Ten thuoc tinh
' Vi du : If ExistsDBProperty("MyProperty") = True Then . . .
'---------------------------------------------------------------------------------------
Function ExistsDBProperty(strPropName As String) As Boolean
On Error Resume Next
Dim db As DAO.Database
Dim prp As DAO.Property
Set db = DBEngine(0)(0)
Set prp = db.Properties(strPropName)
If Not prp Is Nothing Then
ExistsDBProperty = True
Else
ExistsDBProperty = False
End If
Set prp = Nothing
Set db = Nothing
End Function