• Tùy chọn
• Đăng nhập
• Đăng ký
• Xem như trên Máy tính
• Accelerated Mobile Pages Theme

Code tạo sổ phát sinh

• Trang chủ

  • Thủ Thuật Access
  • Access Cơ Bản
  • Forms
  • [Hỏi] Code tạo sổ phát sinh
• Code tạo sổ phát sinh

• RE: Code tạo sổ phát sinh

  Xuân Thanh > 13-06-13, 01:12 PM

  1/ Sory nếu có gì mạo phạm vì không biết bạn là "dân kế toán"
  

  Trích dẫn:Có thể do mình ko phải là dân KToán, chưa hiểu về việc bút toán nên số liệu hơi lôm côm

  
  2/ Bài của bạn có hướng giải quyết (theo yêu cầu của bạn nhé còn theo yêu cầu của kế toán không biết có đúng không nữa). Trong table DinhKhoan thêm một trường Xuly, type Yes/No. Thuật toán như sau :
  - Cho vòng lặp i duyệt từ 1 đến 12 (theo tháng)
  - Cho bien STT = 1
  - Duyệt table tblDanhmuctaikhoan từ đầu đến cuối, đặt SoHieu = SHTK đang xét
  - Duyệt recordset lấy từ table DinhKhoan có Month(Ngaychungtu) = i, TKNo = SoHieu, Xuly = False, Order by theo TKNo và TKCo. Nếu recordset có RecordCount > 0 thì ghi dữ liệu tìm thấy vào SoPhatsinh
  có SCTGS = STT. Sau khi ghi xong Edit trường Xuly về True(để không duyêt lại nữa). Khi Recordcount > 0 thì cho STT tăng lên 1, ngược lại giữ nguyên
  - Tương tự cho TKCo
  - Kết thúc vòng lặp
  - Cuối cùng Edit trường Xuly về False
  
  Toàn bộ code trong modul như sau :
  
  

  Mã PHP:

  Option Compare Database
Option Explicit

Sub LapSo()
    Dim PSN As Recordset, PSC As Recordset
    Dim SO As Recordset
    Dim TK As Recordset
    Dim SoHieu  As String
    Set SO = CurrentDb.OpenRecordset("SoPhatSinh", dbOpenTable)
    If SO.RecordCount > 0 Then
        DoCmd.SetWarnings False
        DoCmd.RunSQL "Delete * From Sophatsinh"
        DoCmd.SetWarnings True
    End If
    Set TK = CurrentDb.OpenRecordset("tblDanhmuctaikhoan", dbOpenTable)
    Dim STT As Integer: STT = 1
    Dim i As Integer
    For i = 1 To 12
        TK.MoveFirst
        Do Until TK.EOF
            SoHieu = TK!SoHieuTK
            Set PSN = CurrentDb.OpenRecordset("Select * From Dinhkhoan Where Month(Ngaychungtu) =" & i & " And TKNo = '" & SoHieu & "'" & " And XuLy = False Order By TKNo, TKCo")
            If PSN.RecordCount > 0 Then
                PSN.MoveFirst
                Do Until PSN.EOF
                    STT = STT
                    SO.AddNew
                    SO!SCTGS = STT
                    SO!Ngay = DateSerial(Year(PSN!Ngaychungtu), Month(PSN!Ngaychungtu) + 1, 1) - 1
                    SO!DienGiai = PSN!DienGiai
                    SO!TKNo = SoHieu
                    SO!TKCo = PSN!TKCo
                    SO!Tien = PSN!Tien
                    SO.Update
                    PSN.Edit
                    PSN!Xuly = True
                    PSN.Update
                    PSN.MoveNext
                Loop
            End If
            If PSN.RecordCount > 0 Then
                STT = STT + 1
            Else
                STT = STT
            End If
            Set PSC = CurrentDb.OpenRecordset("Select * From Dinhkhoan Where Month(Ngaychungtu) =" & i & " And TKCo = '" & SoHieu & "'" & " And Xuly = False Order By TKNo, TKCo")
            If PSC.RecordCount > 0 Then
                PSC.MoveFirst
                Do Until PSC.EOF
                    STT = STT
                    SO.AddNew
                    SO!SCTGS = STT
                    SO!Ngay = DateSerial(Year(PSC!Ngaychungtu), Month(PSC!Ngaychungtu) + 1, 1) - 1
                    SO!DienGiai = PSC!DienGiai
                    SO!TKCo = SoHieu
                    SO!TKNo = PSC!TKNo
                    SO!Tien = PSC!Tien
                    SO.Update
                    PSC.Edit
                    PSC!Xuly = True
                    PSC.Update
                    PSC.MoveNext
                Loop
            End If
            If PSC.RecordCount > 0 Then
                STT = STT + 1
            Else
                STT = STT
            End If
            TK.MoveNext
        Loop
    Next
    Call Update
    PSN.Close: PSC.Close: SO.Close: TK.Close
End Sub

Sub Update()
    Dim rs As Recordset
    Set rs = CurrentDb.OpenRecordset("Dinhkhoan", dbOpenTable)
    If rs.RecordCount > 0 Then
        rs.MoveFirst
        Do Until rs.EOF
            If rs!Xuly = True Then
                rs.Edit
                rs!Xuly = False
                rs.Update
            End If
            rs.MoveNext
        Loop
    End If
    rs.Close
End Sub 


  
  Bạn sử dụng file cũ nhé (File ở bài #1)
  Thân mến
  
  P/S : Gửi cho bạn file đã chỉnh sửa

• RE: Code tạo sổ phát sinh

  Minh Tiên > 14-06-13, 11:03 AM

  Cảm ơn Xuân Thanh rất nhiều !
  Chúc bạn luôn khỏe, thành công, hạnh phúc !
• Bài trước Bài tiếp