• Tùy chọn
• Đăng nhập
• Đăng ký
• Xem như trên Máy tính
• Accelerated Mobile Pages Theme

Cách lưu (back up database) dữ liệu!

• Trang chủ

  • Thủ Thuật Access
  • Access Cơ Bản
  • Thành viên giúp nhau
  • Hướng Dẫn Cách lưu (back up database) dữ liệu!
• Cách lưu (back up database) dữ liệu!

• RE: Cách lưu (back up database) dữ liệu!

  MTNQ > 03-04-15, 03:13 AM

  (31-03-15, 01:12 PM)cpucloi Đã viết: Không phải là không quan tâm, bởi vì mình chưa có nhu cầu Backup Database thôi mà, vẫn theo dõi bài của MatTroiNguQuen đều đấy chứ.
  P/s: Dạo này cũng hơi bận, chỉ thỉnh thoảng vô 4rum thôi.

  
  Chỉ sợ bác cười mình code kiếc lủng củng thui
  

  ---

  (02-04-15, 10:20 AM)chuvoicon Đã viết: Cảm ơn bác MatTroiNguQuen...

  
  Nghe bạn nói tự nhiên thấy có đôi chút an ủi nên sẽ tranh thủ viết tiếp...

• RE: Cách lưu (back up database) dữ liệu!

  maidinhdan > 03-04-15, 09:40 AM

  Xin cảm ơn anh MatTroiNguQuen, chủ đề này rất hay...hằng ngày đều chờ anh cho ra tiếp phần này....
  
  

  (31-03-15, 02:04 AM)MatTroiNguQuen Đã viết: -Nếu có thời gian thì bài viết sau mình sẽ giới thiệu tiếp về FileSystem Object, bổ sung thêm một số tùy chọn:
  + Sao chép đồng thời Compact
  + Sao chép và nén với định dạng RAR, ZIP có đặt password (dĩ nhiên là sẽ có hàm giải nén và phụ hồi CSDL)
  

  
  Em thích nhất Call file Backup lên để Compact thôi....Bởi khi link table và copy để lưu backup thì Data Backup đó nó phìn to thiệt...
  
  Sẽ chờ đợi ....Thk anh.

• RE: Cách lưu (back up database) dữ liệu!

  Xuân Thanh > 03-04-15, 10:33 AM

  Đúng là MatTroiNguQuen. Sao ngủ lâu thế để hôm nay mới dậy? Còn cái xương nào không?
  Viết tiếp chủ đề này đi
  Thân

• RE: Cách lưu (back up database) dữ liệu!

  MTNQ > 01-06-15, 03:47 AM

  Xin lỗi các bác! nợ chủ đề này lâu quá, hôm nay ráng ngồi trả nợ.
  
  -Trong bài này mình làm ví dụ về dùng FileSystemObject để sao chép dữ liệu:
  (Trong ví dụ mình có sử dụng module mdlFileDlg do bác paulsteigel giới thiệu và có chỉnh sửa hàm GetFileOpen để có thể tùy chọn bộ lọc - Filter)
  
  Demo Backup DB 3A.rar
  
  Trong ví dụ trên ta có thể gọi hàm AutoBackUp từ bất cứ đâu để sao chép CSDL
  
  -Trong các bài viết sau mình sẽ lần lượt giới thiệu về hàm CompactDB và các hàm nén/ giải nén có mật khẩu (sử dụng WinRar  Portable, hoặc VszLib.dll và 7z.dll)
  

  ---

  (03-04-15, 09:40 AM)maidinhdan Đã viết: Em thích nhất Call file Backup lên để Compact thôi....Bởi khi link table và copy để lưu backup thì Data Backup đó nó phìn to thiệt...

  
  Hàm  CompactDB mình đang sử dụng:
  
  

  Mã:

  Function CompactDB(strSourceFile As String, Optional strPWD As String, Optional blnBackupSource As Boolean, _
     Optional strBackupFile As String, Optional ByRef strMSG As String) As String
       
    On Error GoTo Err_handler
    
    Dim strCompactFile As String
    Dim MyArr As Variant
    Dim i As Integer
    Dim objEngine As DAO.DBEngine
        
    If FileIsLocked(strSourceFile) Then Exit Function
    
    Set objEngine = Application.DBEngine

    MyArr = ParseFileName(strSourceFile)
   
    DoCmd.Hourglass True
    
    If blnBackupSource Then
        If strBackupFile = "" Then
            strBackupFile = BuildBackupFileName(strSourceFile)
        End If
        If BackupDB(strSourceFile, strBackupFile) = False Then
            strMSG = strMSG & vbCrLf & "-Qua trinh lam gon CSDL khong thanh cong! "
            GoTo Err_Exit
        End If
    End If
    strCompactFile = MyArr(1) & MyArr(2) & "_COMPACTED" & MyArr(3)
        
    If FileSysObj("FileExists", strCompactFile) Then
        FileSysObj "DeleteFile", strCompactFile
    End If
    
Compact:
        DoCmd.Hourglass True
    
        ' Compact CSDL va xuat sang mot tap tin moi (strCompactFile).
        If strPWD <> "" Then
            objEngine.CompactDatabase strSourceFile, strCompactFile, , , ";pwd=" & strPWD
        Else
            objEngine.CompactDatabase strSourceFile, strCompactFile
        End If
        'Neu khong co loi, tuc la qua trinh CompactDatabase hoan thanh thi xoa CSDL hien hanh
        FileSysObj "DeleteFile", strSourceFile
        'Sua ten file da Compact thanh CSDL hien hanh
        If Not FileSysObj("MoveFile", strCompactFile, strSourceFile) Then GoTo Err_Exit
        'Thong bao da hoan tat qua trinh CompactDatabase
        strMSG = strMSG & vbCrLf & "-Lam gon CSDL thanh cong! "
           
Err_Exit:
    DoCmd.Hourglass False
    Set objEngine = Nothing
    Exit Function
   
Err_handler:
    DoCmd.Hourglass False
    If Err.Number = 3031 Then
        i = i + 1
        If i > 1 And i < 4 Then MsgBox "Mat khau khong dung!"
        If i > 3 Then
            strMSG = strMSG & vbCrLf & "-Qua trinh lam gon CSDL khong thanh cong! "
            Resume Err_Exit
        End If
        strPWD = GetPassWord("Vui long cho biet mat khau cua CSDL:", 4 - i)
        If strPWD = "" Then i = 4
        Resume Compact
    Else
        MsgBox Err.Description, vbExclamation, "CompactDB Error: " & Err.Number
        strMSG = strMSG & vbCrLf & "-Qua trinh lam gon CSDL khong thanh cong! "
    End If
    Resume Err_Exit
       
End Function

  
  

  Mã:

  Public Function GetPassWord(Optional Message As String, Optional ingCount As Integer) As String
    Dim strTitle As String, Default As String, MyValue As Variant
    
    strTitle = "Nhap Mat Khau"
    If ingCount <> 0 Then
        Message = Message & vbCrLf & "(Ban con " & ingCount & " lan nhap mat khau!)"
    End If
    Default = "123456"
    MyValue = InputBox(Message, strTitle, Default)
    
    GetPassWord = MyValue
End Function

  
  Hàm liên quan:
  

  Mã:

  Public Function ParseFileName(strPath As String, Optional iRet As Long = -1) As Variant
On Error GoTo Err_handler
    Dim strDrive As String
    Dim strFolderPath As String
    Dim strFullName As String
    Dim strShortName As String
    Dim strFileExt As String
    Dim strElse As String
    
    If strPath = "" Then Exit Function
    
    strDrive = Left$(strPath, InStr(strPath, ":") + 1)
    strFolderPath = Left$(strPath, InStrRev(strPath, "\"))
    strFullName = Mid$(strPath, Len(strFolderPath) + 1)
    
    If InStrRev(strFullName, ".") > 1 Then
        strShortName = Left$(strFullName, InStrRev(strFullName, ".") - 1)
    End If
    strFileExt = Mid$(strFullName, Len(strShortName) + 1)
    strElse = strFolderPath & strShortName
    
    Select Case iRet
    Case -1
        ParseFileName = Array(strDrive, strFolderPath, strShortName, strFileExt, strFullName, strElse)
    Case 0
        ParseFileName = strDrive
    Case 1
        ParseFileName = strFolderPath
    Case 2
        ParseFileName = strShortName
    Case 3
        ParseFileName = strFileExt
    Case 4
        ParseFileName = strFullName
    Case 5
        ParseFileName = strElse
    End Select

Err_Exit:
    Exit Function
   
Err_handler:
    ParseFileName = ""
    MsgBox Err.Description, , "ParseFileName Err: " & Err.Number
    Resume Err_Exit

End Function

• RE: Cách lưu (back up database) dữ liệu!

  chuvoicon > 03-06-15, 12:53 PM

  Nhấp nút "Thanks" Vì "Mặt Zời đã thức dậy"

• RE: Cách lưu (back up database) dữ liệu!

  MTNQ > 09-06-15, 02:40 AM

  Sorry! Demo trên còn một số lỗi chưa kiểm soát hết, mình đã thêm và sửa lại một số hàm nhằm bắt lỗi bằng Tiếng Việt và kiểm soát tốt hơn các khả năng có thể xảy ra:
  
  Demo BackupDB 08-06-15.rar
  

  ---

• RE: Cách lưu (back up database) dữ liệu!

  MTNQ > 09-06-15, 03:39 AM

  Thường thì quá trình sao lưu, CompactDatabase đối với CSDL vài chục MB trở lên cũng tốn một khoảng thời gian không nhỏ nên mình giao nó cho một "thằng con" làm nhiệm vụ backup. Từ chương trình chính gọi nó lên, giao nhiệm vụ, rồi mặc kệ nó, không ảnh hưởng gì đến "thằng cha". Khi nào thành công hay thất bại nó sẽ âm thầm chép vào dữ liệu của "Thằng cha"
  
  Demo BackupDB 09-06-15.rar
  
  Ở đây mình không dùng macro Autoexec hay gọi backup ngay trong sự kiện Formload mục đích là chờ cho quá trình khởi động của "thằng con" hoàn tất, nếu gọi backup ngay trong quá trình khởi động thì "thằng cha" cũng bị treo cho đến khi "thằng con" xong việc (Việc gì cũng phải khởi động hoàn tất rồi mới "hành sự " chứ nhỉ, hùng hục lao vào "lúp bê" ráng chịu )
  
  Code gọi thằng con
  
  

  Mã:

  Public Sub OpenDB(strDbName As String, Optional strPWD As String, Optional blnVisible As Boolean)
On Error GoTo Err_OpenDB
    
    Dim appAccess As Object
    Dim strMyPath As String
     strMyPath = CurrentDb.Name
    
    If strDbName = "" Then
        Exit Sub
    End If
    If Dir$(strDbName) = "" Then
        MsgBox "Khong tim thay tap tin theo duong dan: " & vbCrLf & strDbName
        Exit Sub
    End If
    
    Set appAccess = CreateObject("Access.Application")
    
    If appAccess.SysCmd(7) >= 10 Then
        appAccess.AutomationSecurity = 1
    End If
    
    appAccess.OpenCurrentDatabase strDbName, False, strPWD
    appAccess.Run "CallBackup", strMyPath, blnVisible
    appAccess.Visible = blnVisible
    
Exit_OpenDB:
    Set appAccess = Nothing
    Exit Sub
Err_OpenDB:
    If Err.Number <> 0 Then MsgBox Err.Description, , "OpenDB Error: " & Err.Number
    Resume Exit_OpenDB
End Sub

  
  đoạn code:
  

  Mã:

  If appAccess.SysCmd(7) >= 10 Then
        appAccess.AutomationSecurity = 1
    End If

  dùng cho AC2003 nhằm tắt cửa sổ cảnh báo Security warning khi khởi động chương trình

• RE: Cách lưu (back up database) dữ liệu!

  MTNQ > 02-07-15, 09:25 PM

  Chào các bác!
  MTNQ xin tiếp tục về nén CSDL với  WinRar (Portable)
  
  

  Module nén và giài nén (Click to View)

  
  
  

  Mã:

  Option Compare Database
Option Explicit

#If VBA7 Then
   Private Declare PtrSafe Function OpenProcess Lib "kernel32" _
       (ByVal dwDesiredAccess As Long, _
       ByVal bInheritHandle As Long, _
       ByVal dwProcessId As Long) As Long
   
   Private Declare PtrSafe Function GetExitCodeProcess Lib "kernel32" _
       (ByVal hProcess As Long, _
       lpExitCode As Long) As Long
   
#Else
   Private Declare Function OpenProcess Lib "kernel32" _
       (ByVal dwDesiredAccess As Long, _
       ByVal bInheritHandle As Long, _
       ByVal dwProcessId As Long) As Long
   
   Private Declare Function GetExitCodeProcess Lib "kernel32" _
       (ByVal hProcess As Long, _
       lpExitCode As Long) As Long
   
#End If


Private Const PROCESS_QUERY_INFORMATION = &H400
Private Const STILL_ACTIVE = &H103

Private strWinRarPath As String
Private strErrLogFile As String

Public Function ShellAndWait(ByVal PathName As String, Optional WindowState)
   Dim hProg As Long
   Dim hProcess As Long, ExitCode As Long
   'fill in the missing parameter and execute the program
   If IsMissing(WindowState) Then WindowState = 1
   hProg = Shell(PathName, WindowState)
   'hProg is a "process ID under Win32. To get the process handle:
   hProcess = OpenProcess(PROCESS_QUERY_INFORMATION, False, hProg)
   Do
       'populate Exitcode variable
       GetExitCodeProcess hProcess, ExitCode
       DoEvents
   Loop While ExitCode = STILL_ACTIVE
   
End Function

Public Function WinRarIt(strSourceFile As String, strFormat As String, Optional strMethod As String, _
       Optional strPassword As String, Optional ByRef strMSG As String) As Boolean

   On Error GoTo Err_handler
   
   Dim strFileNameRar As String
   Dim strCMDLine As String
   
   
   WinRarIt = False
   
   If CheckWinRar = False Then Exit Function
   
   strFileNameRar = Left$(strSourceFile, InStrRev(strSourceFile, ".")) & strFormat
   
   strCMDLine = Chr(34) & strWinRarPath & Chr(34) & " m -ep1 -ibck "  '-inul
   
   If strMethod <> "" Then strCMDLine = strCMDLine & strMethod
   
   If strPassword <> "" Then strCMDLine = strCMDLine & " -p" & strPassword
   
   strCMDLine = strCMDLine & " -ilog" & strErrLogFile & " " & Chr(34) & strFileNameRar _
                   & Chr(34) & " " & Chr(34) & strSourceFile & Chr(34)
   
   'Debug.Print strCMDLine
   Call ShellAndWait(strCMDLine, vbHide)
   strSourceFile = strFileNameRar
   
   If Dir(strSourceFile, vbNormal) <> "" Then
       WinRarIt = True
       strMSG = strMSG & vbCrLf & "-Nen CSDL thanh cong"
   Else
       strMSG = strMSG & vbCrLf & "-Nen CSDL That bai"
   End If
Err_Exit:
   Exit Function
Err_handler:
   If Err.Number <> 0 Then MsgBox Err.Description, vbExclamation, "WinRarIt Error: " & Err.Number
   strMSG = strMSG & vbCrLf & "-Nen CSDL That bai "
   Resume Err_Exit
End Function

Public Function UnRarIt(strWinRarFile As String, Optional strUnRarToFolder As String, _
       Optional strPassword As String, Optional ByRef strMSG As String) As Boolean

   On Error GoTo Err_handler
   
   Dim strFileNameRar As String
   Dim strCMDLine As String
   
   UnRarIt = False
   
   If CheckWinRar = False Then Exit Function
   
   If strUnRarToFolder = "" Then
       strUnRarToFolder = Left$(strWinRarFile, InStrRev(strWinRarFile, "\"))
   End If
   
   strCMDLine = Chr(34) & strWinRarPath & Chr(34) & " e -ibck "
   If strPassword <> "" Then strCMDLine = strCMDLine & "-p" & strPassword
   strCMDLine = strCMDLine & " -ilog" & strErrLogFile & " " & Chr(34) & strWinRarFile & Chr(34) _
                   & " " & Chr(34) & strUnRarToFolder & Chr(34)
   
   'Debug.Print strCMDLine
   Call ShellAndWait(strCMDLine, vbHide)
   
   If Dir(strUnRarToFolder) <> "" Then
       UnRarIt = True
       strMSG = strMSG & vbCrLf & "-Giai nen thanh cong"
   Else
       
       strMSG = strMSG & vbCrLf & "-Giai nen that bai"
   End If
   
Err_Exit:
   
   Exit Function
Err_handler:
  If Err.Number <> 0 Then MsgBox Err.Description, vbExclamation, "UnRarIt Error: " & Err.Number
  strMSG = strMSG & vbCrLf & "-Giai nen that bai "
   Resume Err_Exit
End Function

Function CheckWinRar() As Boolean
   strWinRarPath = CurrentProject.path & "\Tools\WinRar\WinRARPortable.exe"
   strErrLogFile = "ErrorLog.txt"
   CheckWinRar = True
   If Dir(strWinRarPath) = "" Then
       MsgBox "Khong tim thay WinRAR theo duong dan: " & vbCrLf & strWinRarPath
       CheckWinRar = False
   End If
End Function

  
  
  

  
  
  Tải ví dụ minh họa:
  BackupToRar (OrZip)

• RE: Cách lưu (back up database) dữ liệu!

  MTNQ > 03-07-15, 12:33 AM

  Trong ví dụ trên:
  
  1- Hàm  ShellAndWait lấy từ trang sau : http://www.rondebruin.nl
     các bạn có thể tham khảo thêm về nén file với WinZip, 7-Zip cũng từ trang trên:
     Zip(Compress) Activeworkbook, folder, file(s) with VBA
  
  2- Class Module: clsBackupCtrlProperties 
     MTNQ viết nhằm mục đích sao lưu  thuộc tính của các điều khiển trên form (ForeColor,BackColor,FontSize,Visible,Enabled,Caption...) , khi cần trả lại trạng thái ban đầu ta chỉ cần gọi hàm Restore
  VD:  obj1.Restore
  MTNQ sẽ giới thiệu chi tiết về Class này trong một chủ đề khác
  
  3- Giải thích các lệnh nén và giải nén của WinRar :
  Command:
  +) m: Move to archive  
     lệnh này tương đương với hai lệnh a (Add files to archive) và -df (Delete files after archiving)
  
  +) -ep1: Loại trừ đường dẫn, chỉ nén file 
     nếu không có lệnh này thì file nén sẽ nằm trong nhiều lớp thư mục cha (có trong đường dẫn)
  
  +) -ibck: Ẩn cửa sổ compression của WinRar khi nén file
  
  +) Tham số : strMethod (phương thức nén) có các giá trị sau:
         -m0   store     do not compress file when adding to archive
         -m1   fastest   use fastest method (less compressive)
         -m2   fast      use fast compression method
         -m3   normal    use normal (default) compression method
         -m4   good      use good compression method (more
                         compressive, but slower)
         -m5   best      use best compression method (slightly more
                         compressive, but slowest)
  
      
  +) -p[pwd] Set password
  
  +) -ilog[name]    Log errors to file
    Trong ví dụ trên thì lỗi trong quá trình nén hoặc giải nén (nếu có) sẽ được ghi vào file ErrorLog.txt  nằm trong thư mục chứa WinRar  (CurrentProject.path & "\Tools\WinRAR\Data\WinRAR\ErrorLog.txt")
  
  +) -inul: Disable all messages 
       Tắt tất cả các thông báo của WinRar 
       (MTNQ không dùng lệnh này trong ví dụ trên nhằm hiển thị các thông báo lỗi )
  
  Hiện tại mình chỉ dùng các lệnh trên thui, nếu có bạn nào thắc mắc về command line của WinRar, WinZip hay 7-Zip thì cửa hỏi nhé

• RE: Cách lưu (back up database) dữ liệu!

  thanhtruong > 06-08-16, 08:34 PM

  Mình thì mình không chia CSDL ra làm BAck end, nó vẫn còn nguyên file.mdb
  Vì chỉnh sửa hoài mà chia ra thì khó làm lắm.
  
  Mình đã làm được là tắt chương trình thì nó tạo ra file.mdb kèm theo ngày tháng năm giờ hiện tại.
  
  Bậy giờ mình muốn thêm vào cái file vừa backup 1 pass thì phải làm sao.
  
  Mình đọc hết mấy bài trên rồi mà không hiểu code nào cho cái file bacup đó pass 123456
  
  Xin mọi người chỉ giáo
• Bài trước Bài tiếp