Đánh giá chủ đề:
  • 0 Votes - 0 Average
  • 1
  • 2
  • 3
  • 4
  • 5
Hỏi cách copy dữ liệu
#1
Tôi có một dữ liệu gồm có một bảng Hoadon và một bang Chuyendoi, hai bảng này nối với nhau bằng một khóa chính là HDID, tôi tạo 1 Form là Hoadon có chứa một Subform Chuyendoi

Khi thực hiện nhập dữ liệu, tôi sẽ nhập ào các trường của Form Hoadon trước rồi nhập vào SubForm Chuyendoi

Tôi muốn : Sau khi nhập xong một bản ghi, có một nút Copy để copy lại toàn bộ dữ liệu của bản ghi hiện tại (Bao gồm cả dữ liệu ở bảng Hoadon và bảng Chuyendoi (để đỡ phải nhập lại, mà chỉ cần chỉnh sửa một số mục cần thiết)

Xin mọi người giúp đỡ, xin chân thành cảm ơn.

http://www.mediafire.com/file/zs3h1jwuc5...euthu3.mdb
Chữ ký của ledangvan Xin chào, mình là ledangvan, Tham gia http://thuthuataccess.com/forum từ ngày 22-08 -11.
ღღღღღTài sản của ledangvan (View All Items) ღღღღღ
Reply
Những người đã cảm ơn
#2
Thủ tục sao chép dữ liệu trên main form + sub form nó tương tự như sau

Mã:
Private Sub SaoChepDL()
On Error GoTo Err_Handler
   
   Dim strSql As String
   Dim lngID As Long
   
   If Me.Dirty Then
       DoCmd.RunCommand acCmdSaveRecord
   End If
   
   If Me.NewRecord Then
       MsgBox "Chua co du lieu de sao chep."
   Else
       
       With Me.Recordset.Clone
           .AddNew
               !SoCT = Me.SoCT
               !NgayCT = Me.NgayCT
               !Diengiai = Nz(Me.Diengiai, "")
               !Donvi = Me.Donvi
           .Update
           .Bookmark = .LastModified
           lngID = !HDID
           If Me.[Chuyendoi Subform].Form.Recordset.Clone.RecordCount > 0 Then
               strSql = "INSERT INTO Chuyendoi(HDID, MSTK,Sotien,NoCo,Nhanvien) " & _
                   "SELECT " & lngID & " As NewID,MSTK,Sotien,NoCo,Nhanvien " & _
                   "FROM [Chuyendoi] WHERE HDID = " & Me.HDID & ";"
               'MTNQ chi lam vi du vai field thoi, ban them cac truong can sao chep vao nhe
               CurrentDb.Execute strSql, dbFailOnError
           Else
               'MsgBox "Chua co du lieu chuyen doi."
           End If
           Me.Bookmark = .LastModified
       End With
   End If

Exit_Handler:
   Exit Sub

Err_Handler:
   MsgBox "Error: " & Err.Number & vbCrLf & Err.Description, , "SaoChepDL"
   Resume Exit_Handler
   
End Sub

MTNQ chỉ làm ví dụ vài trường thôi, bác nhớ thêm các trường cần sao chép vào nhé  007
Chữ ký của MTNQ Thời gian nước chảy... da mòn
Ngủ quên một chốc thấy còn bộ xương!
Reply
Những người đã cảm ơn ledangvan , tvn_hut


Có thể liên quan đến chủ đề
Chủ đề: Tác giả Trả lời: Xem: Bài mới nhất
  [Hỏi] Cách tạo Cbo để lọc các mặt hàng trong Sub Form samacxanh 3 256 17-10-18, 10:33 AM
Bài mới nhất: vulhu06
  [Hỏi] lấy dữ liệu từ query minhminh25767 1 90 20-09-18, 04:51 PM
Bài mới nhất: cpucloi
  [Hỏi] Load dữ liệu từ table lên form bằng lăng 2 179 19-09-18, 04:56 PM
Bài mới nhất: bằng lăng
  [Help] Làm sao để tạo form import dữ liệu từ exel sang table access? hoanglong 2 203 14-09-18, 10:20 AM
Bài mới nhất: duynamvnn1208
  [Hỏi] Cach Tao Class Trong VBA Cuong Servenet 1 212 16-08-18, 06:27 PM
Bài mới nhất: mrsiro

Chuyển nhanh:


User(s) browsing this thread: 1 Guest(s)
Diễn Đàn Thơ Văn Thi Ẩm Lâu|Nhà Hàng Sông Thơ| PMA Nha Trang| Gỗ Acrylic Không Đường Line